root/configure.ac

dnl configure.ac -> Part of Crules Programming language
dnl
dnl Crules is the legal property of its developers. Please refer to the
dnl COPYRIGHT file distributed with this source distribution.
dnl
dnl This program is free software: you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation, either version 3 of the License, or
dnl (at your option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
dnl

AC_PREREQ(2.59)
AC_REVISION($Revision$)

AC_INIT(Crules, 0.46, http://crules.org)
AC_CONFIG_SRCDIR([src/mm_crules.c])
AC_CONFIG_HEADER([src/config.h])
dnl keep the autoconf generated stuff neatly in a folder :)
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])
AM_SANITY_CHECK

dnl Last slash shouldn't be stripped if prefix=/
if test "$prefix" != "/"; then
    prefix=`echo "$prefix" | sed -e 's/\/$//g'`
fi 

dnl Checks for programs.
AC_PROG_CC([icc cl gcc cc])
AC_DEFINE_UNQUOTED([CONFIG_CC], "$CC", [C Compiler used])

AC_PROG_AWK
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_RANLIB
AC_CHECK_PROGS(AR, ar aal, ar)
AC_PROG_CC_C99
AC_PROG_CXX

AC_MSG_CHECKING([Checking for a valid Perl interpreter!])
AC_CHECK_PROGS(PERL, perl, )
AC_PATH_PROGS(PERL, perl, )
if test "x${PERL}" == "x"; then
   AC_MSG_NOTICE([A valid Perl installation is \
required to run the test suite!])
   XPERL="no"
else
   XPERL="yes"
fi

AC_AIX
AC_EXEEXT
AC_GNU_SOURCE

AC_PROG_INSTALL

AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL
AM_PROG_LIBTOOL

AM_PROG_CC_C_O

AC_PROG_YACC
AC_PROG_LEX

AC_C_BIGENDIAN
AC_C_INLINE
AC_C_VOLATILE

AC_CANONICAL_HOST


# CFLAGS_save="$CFLAGS"
# CFLAGS="$"

xpkgs=""
AC_ARG_WITH(maint-str,
  [AS_HELP_STRING([--with-maint-str=""],
    [A Simple Maintainer string!])],
  [xpkgs="$withval"])
if test "x$xpkgs" != "x"; then
  AC_DEFINE_UNQUOTED([MAINTAINER_INFO], "$xpkgs", \
[Maintainer String]) 
fi

# Just to make sure we dont do debug on default!
debug=no
AC_ARG_WITH(debug,
  [AS_HELP_STRING([--with-debug=yes/no],
    [With Debug symbols, default no.])],
  [debug="$withval"])
if test "x$debug" == "xyes"; then
  AC_DEFINE([DEBUG], 1, [Debug Symbols Flag])
  #turn on extra debug compiler options :)
  if test "x$CC" == "xgcc -std=gnu99"; then
     CFLAGS="$CFLAGS -g -O2 -D_DEBUG -ggdb3 -pedantic -Wall -Wextra -fstrict-aliasing"
  fi   
fi

# turn on some optimizations for gcc
# support for other compilers soon
if test "x$debug" == "xno"; then
  if test "x$CC" == "xgcc -std=gnu99"; then
    CFLAGS="$CFLAGS -g -O3 -fwrapv -fstrict-aliasing -ffast-math -fstack-protector"
  fi
fi
# lets get the gcc version :)
CC_VER=""
if test "x$CC" == "xgcc -std=gnu99"; then
   CC_VER=`$CC -dumpversion`
else
   CC_VER="undefined"
fi
AC_DEFINE_UNQUOTED([CONFIG_CC_VER], "$CC_VER", [C Compiler Version])

ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
LIBS="${PTHREAD_LIBS} ${LIBS}"
AM_CFLAGS="${PTHREAD_CFLAGS} ${AM_CFLAGS}" 
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
CC="$PTHREAD_CC"
pthread="yes"

# a lang needs math functions...
AC_CHECK_LIB([m], [pow], , 
  [AC_MSG_ERROR([System Math library is required!])])

# used for constant folding and rounding
AC_CHECK_LIB([gmp], [__gmpz_init], ,
  [AC_MSG_ERROR([GNU MP not found, see http://gmplib.org/])])
AC_CHECK_LIB([mpfr],[mpfr_init] , ,
  [AC_MSG_ERROR([MPFR not found, see http://www.mpfr.org/])])
AC_CHECK_SIZEOF(mp_limb_t, , [#include <gmp.h>])

AC_CHECK_LIB([pcre], [pcre_compile], ,
  [AC_MSG_ERROR([Libpcre3 - Perl Regex not found. \
On Debfian can be found via libpcre3-dev])])

VL_LIB_READLINE
AS_IF([test "x$vl_cv_lib_readline" = "xno"],
      AC_MSG_ERROR([libreadline is required for Crules. \
On Debian this can be found in libreadline5-dev. On RedHat \
this can be found in readline-devel.]))
AC_CHECK_FUNCS(dlopen)

gl_VISIBILITY

GCOV="no"
AC_ARG_WITH(gcov,
  [AS_HELP_STRING([--with-gcov=yes/no],
    [With GCC Code Coverage reporting.])],
  [GCOV="$withval"])
if test "x$GCOV" == "xyes"; then
  if test "x$CC" == "xgcc -std=gnu99"; then
    AC_MSG_NOTICE([Pushing GCC GCOV Support!])
    CFLAGS="$CFLAGS -DGCOV -fprofile-arcs -ftest-coverage"
  else
    AC_MSG_ERROR([GCOV support requires GCC!])
  fi
fi

AC_SUBST(CFLAGS)
AC_SUBST(LDFLAGS)

AC_PATH_PROG(MV, mv, mv)
AC_PATH_PROG(RM, rm, rm)
AC_PATH_PROG(CP, cp, cp)
AC_PATH_PROG(SED, sed, sed)
AC_PATH_PROG(CMP, cmp, cmp)
AC_PATH_PROG(CHMOD, chmod, chmod)
AC_PATH_PROG(HOSTNAME, hostname, hostname)

# Check whether --with-system-type or --without-system-type was given.
AC_ARG_WITH([system-type],
    [AS_HELP_STRING([--with-system-type],
       [Set the system type, like "sun-solaris10"])],
    [SYSTEM_TYPE="$withval"],
    [SYSTEM_TYPE="$host_vendor-$host_os"])
AC_ARG_WITH([machine-type],
    [AS_HELP_STRING([--with-machine-type],
       [Set the machine type, like "sparc"])],
    [MACHINE_TYPE="$withval"],
    [MACHINE_TYPE="$host_cpu"])
AC_SUBST(SYSTEM_TYPE)
AC_DEFINE_UNQUOTED([SYSTEM_TYPE], ["$SYSTEM_TYPE"],
                   [Name of system, eg sun-solaris])
AC_SUBST(MACHINE_TYPE)
AC_DEFINE_UNQUOTED([MACHINE_TYPE], ["$MACHINE_TYPE"],
                   [Machine type name, eg sparc])

AM_INIT_AUTOMAKE

AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(char)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(void*)
AC_CHECK_SIZEOF(short)
AC_CHECK_SIZEOF(double)
AC_CHECK_SIZEOF(float)
AC_CHECK_SIZEOF(size_t)
AC_CHECK_SIZEOF(long int)
AC_CHECK_SIZEOF(long long)
AC_CHECK_SIZEOF(crl_symbol_obj, , \
  [#include "include/crules/symbols.h"])

# Checks for header files.
AC_HEADER_SYS_WAIT
AC_HEADER_STDBOOL
AC_HEADER_STDC
AC_CHECK_HEADERS([stdlib.h string.h stdarg.h unistd.h \
                  stdint.h stdio.h getopt.h \
                  assert.h sys/types.h signal.h \
                  fcntl.h pthread.h sys/wait.h \
                  gmp.h mpfr.h pcre.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_CHECK_FUNCS([popen fopen fclose sprintf fprintf strdup \
                strlen strcpy strcmp getopt_long \
                memcpy calloc system sysconf atoi \
                getpid execl fork wait exit atof \
                vfprintf memcmp getc fgets pipe \
                waitpid fdopen])

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_UTIME_NULL
AC_FUNC_VPRINTF
AC_CONFIG_FILES([Makefile
                 include/Makefile
                 src/Makefile
                 tests/Makefile
                 config/pkg-config/crules.pc])
AC_OUTPUT

echo "---"
echo "Configuration summary for $PACKAGE_NAME version $VERSION"
echo ""
echo "   * Installation prefix:       $prefix"
echo "   * System type:               $SYSTEM_TYPE"
echo "   * Host CPU:                  $host_cpu"
echo "   * C Compiler:                $CC"
echo "   * YACC version:              $YACC"
echo "   * LEX version:               $LEX"
echo "   * Perl support:              $XPERL"
echo "   * GMP & MPFR support:        yes"
echo "   * Perl Regex Support:        yes"
echo "   * POSIX pthreads:            $pthread"
echo "   * DEBUG Symbols:             $debug"
echo "   * GCOV Support:              $GCOV"
echo ""
echo "---"

dnl libtoolize scans configure.ac  and needs to see some text
m4_define([LIBTOOLIZE_AC_INIT], [])